1

I am trying to categorize a SharePoint list of projects into colored approval tracks based on project type using a calculated column. So, depending on the choice from the Project Type column, the calculated column displays a certain color. I am using nested IF( and OR( operators in my formula, but am getting the syntax error message. Can anyone see what's wrong with my formula?

IF(OR([Project Type]="WD",[Project Type]="TAB",[Project Type]="Guide"),"Blue",IF(OR([Project Type]="DP",[Project Type]="Plan",[Project Type]="Report",[Project Type]="Rule",[Project Type]="Waiver"),"Red",IF(OR([Project Type]="BP",[Project Type]="Federal Review"),"Green"),IF(OR([Project Type]="Leg. Analysis",[Project Type]="Correspondence"),"Grey","Gold"))))

Desired outcome:

  • Project Type: WD, TAB, or Guide = Approval Track: Blue
  • Project Type: DP, Plan, Report, Rule, or Waiver = Approval Track: Red
  • Project Type: BP or Federal Review = Approval Track: Green
  • Project Type: Leg. Analysis or Correspondence = Approval Track: Grey
  • All other Project Types = Approval Track: Gold

1 Answer 1

0

There was one extra ) after "Green" in your formula. So, try using this formula like this:

IF(
    OR([Project Type]="WD",[Project Type]="TAB",[Project Type]="Guide"),
    "Blue",
    IF(
        OR([Project Type]="DP",[Project Type]="Plan",[Project Type]="Report",[Project Type]="Rule",[Project Type]="Waiver"),
        "Red",
        IF(
            OR([Project Type]="BP",[Project Type]="Federal Review"),
            "Green",
            IF(
                OR([Project Type]="Leg. Analysis",[Project Type]="Correspondence"),
                "Grey",
                "Gold"
            )
        )
    )
)

Note:

  1. Sometimes comma(,) does not work in formula (it is based on language or regional settings on your site). So in that case use semicolon(;) instead of comma(,).

Official Documentations:

  1. Calculated Field Formulas.
  2. IF function.
1
  • 1
    Yes, thank you! I stared for hours and couldn't find that extra ). Appreciate your help!
    – SamH
    Nov 9, 2022 at 14:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.